Open Menu / arch / arm / lib / elf_aarch64_efi.lds
Loading...
  1
  2
  3
  4
  5
  6
  7
  8
  9
 10
 11
 12
 13
 14
 15
 16
 17
 18
 19
 20
 21
 22
 23
 24
 25
 26
 27
 28
 29
 30
 31
 32
 33
 34
 35
 36
 37
 38
 39
 40
 41
 42
 43
 44
 45
 46
 47
 48
 49
 50
 51
 52
 53
 54
 55
 56
 57
 58
 59
 60
 61
 62
 63
 64
 65
 66
 67
 68
 69
 70
 71
 72
 73
 74
 75
 76
 77
 78
 79
 80
 81
 82
 83
 84
 85
 86
 87
 88
 89
 90
 91
 92
 93
 94
 95
 96
 97
 98
 99
100
101
/* SPDX-License-Identifier: BSD-2-Clause */
/*
 * U-Boot aarch64 EFI linker script
 *
 * Modified from elf_aarch64_efi.lds in gnu-efi
 */

OUTPUT_FORMAT("elf64-littleaarch64", "elf64-littleaarch64", "elf64-littleaarch64")
OUTPUT_ARCH(aarch64)
ENTRY(_start)
SECTIONS
{
	. = 0;
	image_base = .;
	/* .hash and/or .gnu.hash MUST come first! */
	.hash : { *(.hash) }
	.gnu.hash : { *(.gnu.hash) }
	. = ALIGN(4096);
	.eh_frame : { *(.eh_frame) }
	. = ALIGN(4096);
	.text : {
		_text = .;
		*(.text)
		*(.text.*)
		*(.gnu.linkonce.t.*)
		*(.srodata)
		*(.rodata*)
		. = ALIGN(16);
		*(.dynamic);
		. = ALIGN(512);
	}
	. = ALIGN(4096);
	_etext = .;
	_text_size = . - _text;
	. = ALIGN(65536);
	.reloc : {
		KEEP (*(.reloc))
	}
	. = ALIGN(4096);
	.data : {
		_data = .;
		*(.sdata)
		*(.data)
		*(.data1)
		*(.data.*)
		*(.got.plt)
		*(.got)
		/* U-Boot lists and device tree */
		. = ALIGN(8);
		KEEP(*(SORT(__u_boot_list*)));
		. = ALIGN(8);

		/*
		 * The EFI loader doesn't seem to like a .bss section, so we
		 * stick it all into .data:
		 */
		. = ALIGN(16);
		_bss = .;
		*(.sbss)
		*(.scommon)
		*(.dynbss)
		*(.bss)
		*(.bss.*)
		*(COMMON)
		. = ALIGN(512);
		_bss_end = .;
		_edata = .;
		_end = .;
	}
	_data_size = _edata - _data;

	. = ALIGN(4096);
	.rela : {
		*(.rela.text*)
		*(.rela.data*)
		*(.rela.got)
		*(.rela.dyn)
		*(.rela.stab)
		*(.rela.init_array*)
		*(.rela.fini_array*)
		*(.rela.ctors*)
		*(.rela.dtors*)
		*(.rela__u_boot_list*)
	}

	. = ALIGN(4096);
	.dynsym   : { *(.dynsym) }
	. = ALIGN(4096);
	.dynstr   : { *(.dynstr) }
	. = ALIGN(4096);
	.note.gnu.build-id : { *(.note.gnu.build-id) }
	/DISCARD/ : {
		*(.rel.reloc)
		*(.eh_frame)
		*(.note.GNU-stack)
	}
	.embedded_dtb : {
		*(.embedded_dtb)
	}
	.comment 0 : { *(.comment) }
}