Open Menu / arch / sandbox / cpu / u-boot-lib.lds
Loading...
 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
/* SPDX-License-Identifier: GPL-2.0+ */
/*
 * Copyright 2025 Canonical Ltd.
 * Written by Simon Glass <simon.glass@canonical.com>
 *
 * Linker script for U-Boot shared library (libu-boot.so)
 */

SECTIONS
{
	/* Text sections first */
	.text : {
		*(.text*)
	}

	. = ALIGN(32);
	__u_boot_list : {
		KEEP(*(SORT(__u_boot_list*)));
	}

	_u_boot_sandbox_getopt : {
		*(_u_boot_sandbox_getopt_start)
		KEEP(*(_u_boot_sandbox_getopt))
		*(_u_boot_sandbox_getopt_end)
	}

	efi_runtime : {
		__efi_runtime_start = .;
		*(efi_runtime_text)
		*(efi_runtime_data)
		__efi_runtime_stop = .;
	}

	efi_runtime_rel : {
		__efi_runtime_rel_start = .;
		*(.relefi_runtime_text)
		*(.relefi_runtime_data)
		__efi_runtime_rel_stop = .;
	}

	/* Read-only data */
	. = ALIGN(8);
	.rodata : { *(SORT_BY_ALIGNMENT(SORT_BY_NAME(.rodata*))) }

	/* Data sections */
	. = ALIGN(8);
	.data : {
		*(.data*)
	}

	/* BSS section */
	. = ALIGN(8);
	.bss : {
		__bss_start = .;
		*(.bss*)
		*(COMMON)
		. = ALIGN(8);
		__bss_end = .;
	}

	/* Dynamic linking sections for shared library */
	.dynamic : { *(.dynamic) }
	.dynsym : {
		__dyn_sym_start = .;
		*(.dynsym)
		__dyn_sym_end = .;
	}
	.dynstr : { *(.dynstr) }
	.gnu.hash : { *(.gnu.hash) }
	.hash : { *(.hash) }
	.got : { *(.got) }
	.got.plt : { *(.got.plt) }
	.plt : { *(.plt) }
	.rela.dyn : { *(.rela.dyn) }
	.rela.plt : { *(.rela.plt) }

	/* Debugging sections */
	.debug_info 0 : { *(.debug_info) }
	.debug_abbrev 0 : { *(.debug_abbrev) }
	.debug_aranges 0 : { *(.debug_aranges) }
	.debug_ranges 0 : { *(.debug_ranges) }
	.debug_line 0 : { *(.debug_line) }
	.debug_str 0 : { *(.debug_str) }
	.debug_frame 0 : { *(.debug_frame) }
	.debug_loc 0 : { *(.debug_loc) }

	/DISCARD/ : { *(.note*) }
}